第２０回日本数学オリンピック予選（２０１０）問題解法プログラム
サレジオ学院高等学校
数学科教諭　浜田　明巳
パソコン部２年　小西　正人

　現在入試問題でプログラムを出題しているのは，私の知っている限りセンター試験と慶應義塾大学の総合政策，環境情報の両学部だけである．しかし新学習指導要領で数学からプログラムがなくなり，入学試験にも出題されなくなる．過年度生用に選択問題として残るから，当面は出題が続くだろうが，すぐなくなる運命だろう．
　実際数学Ｂの教科書に載っているプログラムを動かすソフトは，ほとんど出回っていない．それを学習せよと言っても無理な話である．私の知っている限りでは，インターネット上にフリーソフトのＷＩＮＢＡＳＩＣや９９ＢＡＳＩＣが載っており，この２つがそのままで教科書のプログラムを動かすことの出来るものである．昔のＮ８８ＢＡＳＩＣやＦＢＡＳＩＣが動けば，当然それで良い．しかし最近のＯＳのバージョンアップに伴い，パソコンを買い換える際に，ＢＡＳＩＣを再インストールした人は大変少ないのではないか．そもそもＮ８８ＢＡＳＩＣはＷＩＮＤＯＷＳ上では動かない．多少プログラムを手直しすれば，十進ＢＡＳＩＣやＵＢＡＳＩＣでも動くが，まったく同じものではない．
　プログラムに関しては，既に情報の授業で習うものとなっているので，今後はそちらの方で頑張るしかないのだろう．私の学校でも，ＥＸＣＥＬのマクロやＶＢＳＣＲＩＰＴを情報で学習している．大学の理系の授業では，情報でＣ言語や，ＦＯＲＴＲＡＮなどを学ぶと聞く．１つのプログラム言語を知っていれば，他の言語の習得も容易くなるはずだ．
　予備校のセンター試験解説を聞くと，プログラムを選択した者の得点は，出来る，出来ないの差がはっきり表れているという．約数，倍数の問題など，決まり切っているものが多いので，あらかじめ学習しておけば，高得点は十分期待出来る．パソコン好きの生徒にとっては，ベクトルや数列よりも点は取りやすい．少なくとも選択の幅が広くなり，有利となるのは間違いない．
　最後のあがきとして，プログラムを投稿したい．
　１２題の中で，１，２，３，４が初歩的なプログラム（For Next）で解ける問題，５，７，１０がプログラム自体は簡単だが（For Next，再帰），解くのに大変な時間がかかってしまう問題，８，１１が図形問題で特殊な方法で解くもの．そして問題６，９，１２は解けなかった．桁数が多くなったり，次数が高すぎたりして，コンピュータ向きではないからだ．
　ＥＸＣＥＬのマクロの作成方法は次の通り．メニューバーにおいて，
　　ツール
　　マクロ
　　マクロ
　　マクロ名記入　または　作成　または　編集
で，マクロを記入開始．バージョンによって多少の違いがある．マクロのセキュリティレベルを最低にしておく事も必要である．
　グラフ表示ソフトのＧＲＡＰＥＳは，
　　http://www.osaka-kyoiku.ac.jp/~tomodak/grapes/index.html
からダウンロード出来るフリーソフトである．スクリプト（プログラム）も組む事が出来るので，図形問題だけでなく，計算問題も解く事が出来る．講談社ブルーバックス等で詳しい解説書が出ている．２，３ヶ月に１回はバージョンアップしているので，時々チェックしておくべきだ．
　十進ＢＡＳＩＣは，
　　http://www.vector.co.jp/authors/VA008683/
からダウンロード出来るフリーソフトである．扱う数学関数も豊富であり，数学の先生向きのソフトである．有理数計算，多桁計算も出来る．図形表示も簡単である．
　ＵＢＡＳＩＣは，
　　http://www.rkmath.rikkyo.ac.jp/%7Ekida/ubasic.htm
からダウンロード出来るフリーソフトである．計算能力にかけては，これに勝るソフトはない．１０００の階乗もあっという間に計算出来る．扱う数学関数も豊富であり，有理数計算，多項式計算も出来る．
　上記以外のソフト（一太郎，ＣＡＢＲＩ，ＶＩＳＵＡＬ　ＢＡＳＩＣ等）でも解法プログラムを作ったので，もし興味があるのなら，サレジオ学院高等学校浜田宛で，その旨連絡して下さい．メールでプログラムを配布したいと思っています（※）．

（※）〒２２４−００２９　神奈川県横浜市都筑区南山田３−４３−１
　　　　　　　　　　　　　　サレジオ学院高等学校　浜田　明巳
　　　　メールアドレス：akemi_hamada0213@yahoo.co.jp

  　　　　　　　　　　　　　　参考文献：数学オリンピック財団Web Site
 　　　　　　　　　　　　　　　　　　　大学への数学　２０１０年３月号　東京出版
  　　　　　　　　　　　　　　　　　　　神奈川数学部会通信　２０１０年

第２０回日本数学オリンピック予選（２０１０）問題１
　ａ＞ｂ＞ｃ＞ｄ＞ｅ＞ｆをみたし，ａ＋ｆ＝ｂ＋ｅ＝ｃ＋ｄ＝２２となるような正の整数の組（ａ，ｂ，ｃ，ｄ，ｅ，ｆ）はいくつあるか．

作成者：パソコン部２年　小西　正人
（Ｃ＋＋編）
#include<iostream.h>
void main(){
 int kotae;
 int j;
 int i;
 int k;
 kotae=0;
 for(j=1; j<=10; j++){
  for(i=j+1; i<=10; i++){
   for(k=i+1; k<=10; k++){
    kotae++;
   }
  }
 }
 cout << kotae << endl;

}

作成者：数学科教諭　浜田　明巳
　典型的なFor Nextプログラムである．一番数が小さいｆをFor Nextで回す
（１≦ｆ≦２２−５）．その都度ａ＝２２−ｆでａを求め，ａ＞ｆの時，次に小さいｅをFor Nextで回す（ｆ＋１≦ｅ≦ａ−４）．ｂ＝２２−ｅでｂを求め，ａ＞ｂ＞ｅの時，ｄをFor Nextで回す（ｅ＋１≦ｄ≦ｂ−２）．ｂ＞ｃ＞ｄの時カウントし，最終的に答を表示する．ＥＸＣＥＬでは，すべてのａ，ｂ，ｃ，ｄ，ｅ，ｆの組も表示するようにしてある．このようにＥＸＣＥＬはすべての解を表示するのに最適なソフトである．
　このプログラムにより，答は１２０組である事が分かる．

（ＢＡＳＩＣ編，センター試験仕様）
100 LET K=0
110 FOR F=1 TO 22-5
120    LET A=22-F
130    IF A<=F THEN GOTO 240
140    FOR E=F+1 TO A-4
150       LET B=22-E
160       IF A<=B OR B<=E THEN GOTO 230
170       FOR D=E+1 TO B-2
180          LET C=22-D
190          IF B<=C OR C<=D THEN GOTO 220
200          LET K=K+1
210          PRINT K;A;B;C;D;E;F
220       NEXT D
230    NEXT E
240 NEXT F
250 END

第２０回日本数学オリンピック予選（２０１０）問題２
　０以上１００００以下の整数の中で，１０進法で表記したときに１が現れないようなものすべての平均を求めよ．

作成者：数学科教諭　浜田　明巳
　典型的なFor Nextプログラムである．この整数をｎとすると，０≦ｎ≦９９９９となり高々４桁である．一の位をｎ１，十の位をｎ２，百の位をｎ３，千の位をｎ４と
し，それぞれをFor Nextで回す（０≦ｎ１，ｎ２，ｎ３，ｎ４≦９）．ただしｎ１，
ｎ２，ｎ３，ｎ４≠１（If文使用）．ｎの個数を分母に，ｎの和を分子にして，最後に分母，分子の最大公約数を計算して，割り算をして，答の分数を求める．最大公約数を計算する際に再帰を使っている．
　このプログラムにより，答は４８８８４／９である事が分かる．

（ＥＸＣＥＬマクロ）
Option Explicit
Sub jmo1002()
    Dim n1 As Integer '一の位
    Dim n2 As Integer '十の位
    Dim n3 As Integer '百の位
    Dim n4 As Integer '千の位
    Dim g As Long '分母,分子の最大公約数
    Cells(1, 1).Value = 0 '答の分子
    Cells(1, 2).Value = 0 '答の分母
    Range("A1").Select
    For n1 = 0 To 9
      If n1 <> 1 Then
        For n2 = 0 To 9
          If n2 <> 1 Then
            For n3 = 0 To 9
              If n3 <> 1 Then
                For n4 = 0 To 9
                  If n4 <> 1 Then
                    Cells(1, 2).Value = Cells(1, 2).Value + 1
                    Cells(1, 1).Value = Cells(1, 1).Value + (n1 + n2 * 10 + n3 * 100 + n4 * 1000)
                  End If
                Next n4
              End If
            Next n3
          End If
        Next n2
      End If
    Next n1
    g = GCM(Cells(1, 1).Value, Cells(1, 2).Value)
    Cells(1, 1).Value = Cells(1, 1).Value / g
    Cells(1, 2).Value = Cells(1, 2).Value / g
End Sub
Private Function GCM(ByVal a As Long, ByVal b As Long) As Long
    If b = 0 Then
      GCM = a
    Else
      GCM = GCM(b, a Mod b)
    End If
End Function

第２０回日本数学オリンピック予選（２０１０）問題３
　各桁の数字が相異なり，どれも０でないような３桁の正の整数ｎがある．ｎの各桁の数字を並べ替えてできる６つの数の最大公約数をｇとする．ｇとして考えられる最大の値を求めよ．

作成者：数学科教諭　浜田　明巳
　典型的なFor Nextプログラムである．ｎの各桁の数をｎ１，ｎ２，ｎ３とする．対称性を考えて，ｎ１＜ｎ２＜ｎ３としてよい．For Nextでｎ１，ｎ２，ｎ３を回し
（１≦ｎ１≦９−２，ｎ１＋１≦ｎ２≦９−１，ｎ２＋１≦ｎ３≦９），それぞれの場合の位を代えた６個の整数の最大公約数を求め，その中で最大のものを求める．
　このプログラムにより，答は１８で，ｎ＝４６８の時である事が分かる．

（ＥＸＣＥＬマクロ）
Option Explicit
Sub jmo1003()
    Dim n1 As Integer 'nの各桁,n1<n2<n3
    Dim n2 As Integer
    Dim n3 As Integer
    Dim g As Integer '最大公約数
    Cells(1, 1).Value = 0 '答
    Cells(2, 1).Value = 0 '答の個数
    For n1 = 1 To 9 - 2
      For n2 = n1 + 1 To 9 - 1
        For n3 = n2 + 1 To 9
          g = GCM(n1 * 100 + n2 * 10 + n3, n1 * 100 + n3 * 10 + n2)
          g = GCM(g, n2 * 100 + n1 * 10 + n3)
          g = GCM(g, n2 * 100 + n3 * 10 + n1)
          g = GCM(g, n3 * 100 + n1 * 10 + n2)
          g = GCM(g, n3 * 100 + n2 * 10 + n1)
          If Cells(1, 1).Value < g Then
            Cells(1, 1).Value = g
            Cells(2, 1).Value = 1
            Columns("B:B").Select
            Selection.ClearContents
            Range("A1").Select
            Cells(1, 2).Value = n1 * 100 + n2 * 10 + n3
          ElseIf Cells(1, 1).Value = g Then
            Cells(2, 1).Value = Cells(2, 1).Value + 1
            Cells(Cells(2, 1).Value, 2).Value = n1 * 100 + n2 * 10 + n3
          End If
        Next n3
      Next n2
    Next n1
End Sub
Private Function GCM(ByVal a As Integer, ByVal b As Integer) As Integer
    If b = 0 Then
      GCM = a
    Else
      GCM = GCM(b, a Mod b)
    End If
End Function